Come rimuovere l'attributo di sola lettura in modo ricorsivo su Windows 7

Io userei il comando ATTRIB, per esempio:

attrib -r c:\folder\*.* /s

attrib è il comando -r è il flag per rimuovere gli attributi di sola lettura c:\folder\*.* è la cartella su cui lo stai eseguendo, più i caratteri jolly per tutti i file /s è il flag per fare tutte le sottodirectory e i file

Ecco altra documentazione ed esempi per il comando attrib: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/attrib

Per prima cosa, aprite un prompt dei comandi. Poi cd nella directory dove volete iniziare ad applicare le modifiche agli attributi. Infine, inserite il seguente comando:

attrib -R /S

Questo rimuoverà l'attributo di sola lettura da tutti i file nella directory corrente, poi ricorrerà in basso per fare la stessa cosa in tutte le sottodirectory.

• Technet - attrib

Nota: La maggior parte delle altre risposte sta usando solo -r che potrebbe non funzionare su file che hanno system o hidden attributi impostati.

Ecco una soluzione per rimuovere ricorsivamente l'attributo di sola lettura da tutti i file (inclusi quelli di sistema o nascosti) all'interno di una directory:

attrib -s -h -r "c:\path_to_folder\*.*" /s /d

Descrizione: -s Rimuovi attributo di sistema -h Rimuovi attributo nascosto -r Rimuovi attributo di sola lettura/s Imposta/rimuovi attributi nella cartella corrente e incluse le sottocartelle/d Imposta/rimuovi anche attributi delle cartelle

Ho creato questo file batch per fare questo. Fondamentalmente questo file batch cancellerà gli attributi di sola lettura nella directory in cui si trova o la directory in cui si trova e tutte le directory inferiori. Spero che qualcuno trovi un uso per questo. Scusate il codice che può sembrare “povero” perché sto appena iniziando a imparare i file batch.

@ECHO off
:begin
ECHO Would you like to only remove read only attributes
ECHO from this director or from all the sub directores as
ECHO well?
ECHO.
ECHO [A] This directory only
ECHO [B] All directories - cascading
ECHO [C] Cancel
SET /P actionChoice="Option(A,B,C): "
ECHO.
IF "%actionChoice%" == "A" GOTO A
IF "%actionChoice%" == "B" GOTO B
IF "%actionChoice%" == "C" GOTO C
GOTO badChoice

:A
CLS
ECHO Are you sure you want to remove all read-only
ECHO attributes from this directory only?
ECHO.
ECHO Directory:
ECHO.
ECHO %CD%
ECHO.
SET /P continueChoice="Continue? (Y, N): "
IF "%continueChoice%" == "N" GOTO abort
ECHO Removing Read Only Attributes From Local Directory...
SET currectDirectory=%CD%
ECHO Current directory is: %currectDirectory%
FOR %%G IN (%currectDirectory%\*) DO (
ECHO %%G
ATTRIB -R "%%G"
)
GOTO end

:B
CLS
ECHO Are you sure you want to remove all read-only
ECHO attributes from this directory and all sub-directories?
ECHO.
ECHO Directory:
ECHO.
ECHO %CD%
ECHO.
SET /P continueChoice="Continue? (Y, N): "
IF "%continueChoice%" == "N" GOTO abort
ECHO Removing Read Only Attributes Cascading...
FOR /R %%f IN (*) DO (
ECHO %%f
ATTRIB -R "%%f"
)
GOTO end

:C
CLS
ECHO Cancel: no files have been changed
GOTO end

:badChoice
CLS
ECHO Unknown Option
ECHO.
ECHO.
ECHO.
GOTO begin

:abort
CLS
ECHO No files have been changed
ECHO.
ECHO.
ECHO.
GOTO begin

:end
ECHO Read only attributes removed
PAUSE

Molte opzioni qui, ma questo file batch supporta il drop di cartelle e/o file nel file batch stesso.

Salva questo codice sotto a Read-only Off.bat.

Nota per come funziona il bit di drop all'interno del codice.

@echo off
title ' %~nx0 ' by stephen147
color 5F
rem Place this inside a folder and run to remove the read-only attribute in the root folder and any folders or files within.
rem Or drop the folder/s and/or file/s to the batch file itself.
cd /d "%~dp0"
echo.
echo.Do you want to remove the read-only attributes inside this folder ? [Ctrl + C to cancel]
echo.
pause
echo.
echo.%cd%
attrib -s -d -r "%cd%\*.*"
attrib -s -d -r "%cd%"
rem This line supports dropping the folder/s and/or file/s to the batch file itself.
attrib -r "%*"
echo.
echo.Done
timeout /T 5
EXIT