Dopo una nuova installazione di Windows - XP o 7 - come posso “forzare” gli aggiornamenti di Windows?
Non voglio avere aggiornamenti di Windows “vecchi” dopo una settimana, quindi potrebbe essere fatto in “un solo passo”? Ci sono dei comandi “magici” che forzano Windows a controllare gli aggiornamenti e, se ce ne sono, a installarli?
Oltre al solito modo di usare Windows Update, potete forzare un controllo da una linea di comando.
Aprite un prompt dei comandi di amministratore ed eseguite:
C:\> %windir%\system32\wuauclt.exe /detectnow
Wuauclt.exe è il client AutoUpdate di Windows Update e viene usato per controllare gli aggiornamenti disponibili (per le varie versioni della piattaforma MS Windows) da Microsoft Update.
Questo non forzerà un'installazione.
È possibile controllare e installare automaticamente gli aggiornamenti utilizzando uno script. Questo funzionerà sia in XP che in Windows 7.
Ci sono diversi script disponibili per il download, ecco il mio :
' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain. It may be freely
' used, modified, and distributed. However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
' 0 = scripting failure
' 1 = error obtaining or installing updates
' 2 = installation successful, no further updates to install
' 3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()
Do
WScript.Echo
WScript.Echo "Searching for approved updates ..."
WScript.Echo
Set updateSearch = updateSearcher.Search("IsInstalled=0")
If updateSearch.ResultCode <> 2 Then
WScript.Echo "Search failed with result code", updateSearch.ResultCode
WScript.Quit 1
End If
If updateSearch.Updates.Count = 0 Then
WScript.Echo "There are no updates to install."
WScript.Quit 2
End If
Set updateList = updateSearch.Updates
For I = 0 to updateSearch.Updates.Count - 1
Set update = updateList.Item(I)
WScript.Echo "Update found:", update.Title
Next
WScript.Echo
updateDownloader.Updates = updateList
updateDownloader.Priority = 3
Set downloadResult = updateDownloader.Download()
If downloadResult.ResultCode <> 2 Then
WScript.Echo "Download failed with result code", downloadResult.ResultCode
WScript.Echo
WScript.Quit 1
End If
WScript.Echo "Download complete. Installing updates ..."
WScript.Echo
updateInstaller.Updates = updateList
Set installationResult = updateInstaller.Install()
If installationResult.ResultCode <> 2 Then
WScript.Echo "Installation failed with result code", installationResult.ResultCode
For I = 0 to updateList.Count - 1
Set updateInstallationResult = installationResult.GetUpdateResult(I)
WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode
Next
WScript.Quit 1
End If
If installationResult.RebootRequired Then
WScript.Echo "The system must be rebooted to complete installation."
WScript.Quit 3
End If
WScript.Echo "Installation complete."
Loop
Lo esegui dalla riga di comando in questo modo:
cscript wsusupdate.vbs
Il mio script è solo minimamente funzionale ma può comunque essere utile. Ci sono altri script di questo tipo disponibili con molte caratteristiche aggiuntive, provate a fare una ricerca su Google.
Un altro modo per forzare una vera scansione degli aggiornamenti è quello di fare tabula rasa, cancellando tutti gli aggiornamenti memorizzati in %windir%\Windows\SoftwareDistribution\Download :
NET STOP wuauserv
RD /S /Q %windir%\SoftwareDistribution\Download
NET START wuauserv
Poi vai su Windows Update, e “Controlla gli aggiornamenti”. Potrebbe volerci un'ora, perché ogni file aggiornabile sul vostro volume di sistema viene controllato (i successivi “Controlli per gli aggiornamenti” saranno veloci). Questo approccio elimina gli errori, gli aggiornamenti pasticciati, e produce un sistema pulito e aggiornato, almeno per come lo vede MS.
Sto usando uno strumento di seconda parte chiamato wuinstall per aggiornare l'installazione fresca di windows. con questo puoi automatizzare l'intero processo di aggiornamento, inclusi i riavvii automatici. penso che sia uno dei modi più veloci per ottenere un windows fresco e aggiornato senza la presenza dell'utente.
Ho scoperto che se, come parte della tua nuova installazione su Windows 7, hai aggiornato IE o non hai ancora eseguito IE e risposto alle domande introduttive, Windows Update ti darà un errore. Inoltre non ho trovato un modo per passare Windows Update a Microsoft Update senza passare attraverso la GUI, quindi accendo manualmente IE, lo faccio inizializzare e poi configuro Windows Update attraverso la GUI, così posso passare a Microsoft Update ed evitare l'errore iniziale. Il tuo chilometraggio può variare.